unset key
set xrange [-350:-160]
set yrange [0:1.5]
set xlabel "Millions of years ago" offset 0,0.5
set tics scale 0.33
unset ytics
unset grid

# High oxygen. Read off from figure in Perspective Atmospheric oxygen over
# Phanerozoic time; PNAS Vol. 96, Issue 20, 10955-10957, September 28, 1999
# Followed by a 60 Myr period of unusually low oxygen concentrations, before
# going returning to the norm
set object rectangle from -370   ,0.55 to -345   ,0.95 lw 0 fc rgb "#ddddff" # >21
set object rectangle from -345   ,0.55 to -328   ,0.95 lw 0 fc rgb "#bbbbff" # >25
set object rectangle from -328   ,0.55 to -305   ,0.95 lw 0 fc rgb "#9999ff" # >30
set object rectangle from -305   ,0.55 to -287   ,0.95 lw 0 fc rgb "#7777ff" # >35
set object rectangle from -287   ,0.55 to -272   ,0.95 lw 0 fc rgb "#9999ff" # >30
set object rectangle from -272   ,0.55 to -259   ,0.95 lw 0 fc rgb "#bbbbff" # >25
set object rectangle from -259   ,0.55 to -248   ,0.95 lw 0 fc rgb "#ddddff" front # >21
set object rectangle from -248   ,0.55 to -215   ,0.95 lw 0 fc rgb "#dd99ff" # low
set object rectangle from -215   ,0.55 to  -70   ,0.95 lw 0 fc rgb "#ddddff" # >21
set label "High oxygen concentration" at (-350+-248)/2,0.83 center font ",22"
set label ">25%" at (-345+-328)/2,0.68 center font ",14"
set label ">30%" at (-328+-305)/2,0.68 center font ",14"
set label ">35%" at (-305+-287)/2,0.68 center font ",14"
set label ">30%" at (-287+-272)/2,0.68 center font ",14"
set label ">25%" at (-272+-259)/2,0.68 center font ",14"
set label ">21%" at (-259+-248)/2,0.68 center font ",14" front
set label "Low oxygen" at (-248+-215)/2,0.83 center font ",22"
set label "≈16%" at (-248+-215)/2,0.65 center font ",14"
set label "Normal oxygen" at (-215+-160)/2,0.83 center font ",22"
set label "20-23%" at (-215+-160)/2,0.65 center font ",14"

# Meganisoptera
# Start from https://www.britannica.com/animal/Odonata/Evolution-paleontology-and-classification
# End from The Odonatoptera of the Late Permian Lodève Basin Journal of Iberian Geology 34 (1) 2008: 115-122
set object rectangle from -359   ,1.05 to -252-10,1.45 lw 0 fc rgb "#ff9999"
set object rectangle from -252-10,1.05 to -252+10,1.45 lw 0 fc rgb "#ffdddd" front
set label "Giant griffinflies" at (-359+-252)/2,1.25 center font ",22"
set label "{/=14Extinction}\n{/=14roughly}\n{/=14here}" at -252,1.32 center font ",8" front

# Pterosaurs
# From https://en.wikipedia.org/wiki/Pterosaur
# Divergence from non-flying ancestors from here https://www.nature.com/articles/s41586-020-2858-8
set object rectangle from -245   ,0.05 to  -228  ,0.45 lw 0 fc rgb "#ccffcc"
set object rectangle from -228   ,0.05 to  -66   ,0.45 lw 0 fc rgb "#77ff77"
set label "Pterosaurs" at (-245+15+-160)/2,0.30 center font ",22"
set label "Insects lose monopoly on flight" at (-245+15+-160)/2,0.15 center font ",14"
set label "{/=14Pterosaurs}\n{/=14develop flight}\n{/=14around here}" at (-245+-228)/2,0.30 center font ",8"

# Permian-Triassic mass extinction
set arrow from -251.9,0 to -251.9,1.5 lw 2 dt 3 nohead
set label "{/=18Permian-Triassic}\n{/=18mass extinction}" at -270,0.35 right font ",12"
set arrow from -270,0.29 to -251.9,0.29 lt 1 lw 2

set term svg size 800,300 font ",16"
set output "griffinfly_oxygen.svg"
plot -100